class ControlPoint {
  int w = 3;
  int x, y;
  String name;
  
  ControlPoint(int x, int y, String name){
    this.x = x;
    this.y = y;
    this.name = name;
  }
  
  void display(int mx, int my){
    fill(255);
    if(isHit(mx, my))
      stroke(255,0,0);
    else
      stroke(40,40,40);
    rect(x-w, y-w, 2*w, 2*w);
  }

  boolean isHit(int tx, int ty){
    return tx >= x-w && tx < x + w && ty >= y-w && ty < y + w;
  }
}

ControlPoint [] cps = new ControlPoint[4];

void setup(){
  size(400,400);

  for(int i=0; i<cps.length;i++){
    cps[i] = new ControlPoint(50+100*i, 100 + (i % 2)*200, "p" + i);
  }
}

double[] calcBezier(double t){
  double dd[] = new double[2];
  double s = 1.0 - t;
  dd[0] = s*s*s*cps[0].x+3*s*s*t*cps[1].x+3*s*t*t*cps[2].x+t*t*t*cps[3].x;
  dd[1] = s*s*s*cps[0].y+3*s*s*t*cps[1].y+3*s*t*t*cps[2].y+t*t*t*cps[3].y;
  // print(String.format("t=%3.1f x=%6.2f y=%6.2f%n",t, dd[0], dd[1]));
  return dd;
}

void draw(){
  int i;
  int mx = mouseX;
  int my = mouseY;
  background(204);

  stroke(0,128,0);
  for(i=0; i<cps.length-1; i++){
    line(cps[i].x, cps[i].y, cps[i+1].x, cps[i+1].y);
  }

  stroke(128,128,200);
  noFill();
  bezier(cps[0].x, cps[0].y, cps[1].x, cps[1].y,
	 cps[2].x, cps[2].y, cps[3].x, cps[3].y); 

  double t;
  float r=2;
  fill(255,0,0);
  noStroke();
  for(t=0.0; t <= 1.0; t+=0.05){
    double[] dd = calcBezier(t);
    // point((float)dd[0], (float)dd[1]);
    ellipse((float)dd[0], (float)dd[1], r*2, r*2);
  }

  
  for(i=0; i<cps.length; i++){
    cps[i].display(mx,my);
  }
}

ControlPoint draggingObj;

void mousePressed(){
  int mx = mouseX;
  int my = mouseY;

  draggingObj = null;
  for(int i=0; i<cps.length; i++){
    if(cps[i].isHit(mx, my)){
      draggingObj = cps[i];
      break;
    }
  }
}

void mouseDragged(){
  if(draggingObj != null){
    draggingObj.x = mouseX;
    draggingObj.y = mouseY;
    redraw();
  }
}


/*** Local Variables:  ***/
/*** mode: java        ***/
/*** tab-width: 8      ***/
/*** c-basic-offset: 2 ***/
/*** End:              ***/